home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 2000 #1 / Amiga Plus CD - 2000 - No. 1.iso / Games / Starter / JST / Developer / sources / src / loaders / jst / jst_deg.asm < prev    next >
Encoding:
Assembly Source File  |  1999-12-03  |  11.2 KB  |  745 lines
  1. ; *** JOTD HD Startup utility library
  2. ; *** Copyright Jean-Francois Fabre 1996-1998
  3. ; 
  4. ; *** Sprite degrade part Copyright Bert Jahn 1996
  5.  
  6. ; *** degrader part. Other parts are not distributed
  7.  
  8. ; If you use this source (or parts), I'd appreciate
  9. ; that you credit me about it. Thanks
  10. ;
  11.     ; *** For link with C programs
  12.  
  13. ;;    XDEF    _C_Degrade
  14. ;;    XDEF    _C_Enhance
  15.  
  16. ;;    XDEF    _Enhance
  17. ;;    XDEF    _Degrade
  18. ;;    XDEF    _DegradeCpu
  19. ;;    XDEF    _DegradeGfx
  20.  
  21. ;;    XDEF    _FlushCachesSys
  22.  
  23. ;;    XDEF    _Kick37Test
  24. ;;    XDEF    _KickVerTest
  25.  
  26. RESET_CIA_CODE:MACRO
  27.  
  28. ResetCIAs:
  29.     move.b  #$c0,$bfd200            ;reinit CIAs
  30.     move.b  #$ff,$bfd300            ;for
  31.     move.b  #$03,$bfe201            ;KB
  32. ;    move.b  #$7f,$bfec01
  33.     move.b  #$00,$bfee01
  34.     move.b  #$88,$bfed01
  35.  
  36.     tst.b    $bfdd00            ; acknowledge CIA-B Timer A interrupt
  37.     tst.b    $bfed01            ; acknowledge CIA-A interrupts
  38.  
  39.     bsr    AckKeyboard
  40.  
  41.     rts
  42.  
  43. AckKeyboard:
  44.     bset    #$06,$BFEE01
  45.     move.l    D0,-(A7)
  46.     moveq.l    #1,D0
  47.     IFD    HDSTARTUP
  48.     bsr    RelFun_BeamDelay
  49.     ENDC
  50.     move.l    (A7)+,D0
  51.     bclr    #$06,$BFEE01
  52.     rts
  53.     ENDM
  54.  
  55.     IFND    HDSTARTUP
  56.  
  57.     ; *** this code is on its own (which is the case :-) )
  58.     
  59. _SysBase = 4
  60.  
  61.     include    "libs.i"
  62.     include    "jst_macros.i"
  63.  
  64.     ENDC
  65.  
  66.  
  67. ; *** Restore degraded things: Display, Caches, VBR...
  68.  
  69. ; internal use (in InGameExitAbs)
  70.  
  71. ;;_C_Enhance:
  72. ;;_Enhance:
  73. AbsFun_Enhance:
  74.     STORE_REGS
  75.  
  76.     tst.b    degraded_cpu
  77.     beq    skipec$
  78.  
  79.     move.l    oldcacheset(pc),D0
  80.     moveq.l    #-1,D1
  81.     bsr    EnaCaches
  82.  
  83.     move.l    oldvbr(pc),D0
  84.     bsr    SetVBR
  85.  
  86. skipec$
  87.     tst.b    degraded_gfx
  88.     beq    exit$
  89.  
  90.     move.l    _SysBase,A6
  91.     JSRLIB    Disable
  92.  
  93.     move.l    _GfxBase,D0
  94.     beq    1$
  95.  
  96.     lea    $DFF000,A5
  97.     move.l    my_copinit(PC),cop1lc(a5) ; adresse du début de la liste
  98.  
  99.     move.l    D0,A6
  100.  
  101.     bsr    EnhanceBandWidth
  102.  
  103.     move.l    my_actiview(PC),D0
  104.     beq    1$
  105.     move.l    D0,A1
  106.  
  107.     JSRLIB    LoadView
  108.     JSRLIB    WaitTOF
  109.     JSRLIB    WaitTOF
  110.  
  111. 1$
  112.     move.l    _SysBase,A6
  113.     JSRLIB    Enable
  114.  
  115.     move.l    _IntuitionBase,D0
  116.     beq    skip$
  117.     move.l    D0,A6
  118.     move.l    TheScreen,D0
  119.     beq    skip$
  120.  
  121.     bsr    EnhanceSprites
  122.  
  123.     move.l    TheScreen,D0
  124.     move.l    D0,A0
  125.     move.l    TheScreen,A0
  126.     JSRLIB    CloseScreen
  127.  
  128.     bsr    CloseIntuiLib
  129. skip$
  130.     bsr    CloseGFXLib
  131. exit$
  132.  
  133.     RESTORE_REGS
  134.     rts
  135.  
  136. DegradeBandWidth:
  137.     STORE_REGS
  138.     clr.b    degraded_bdw
  139.     move.l    (_GfxBase),a6
  140.     cmp.l    #39,(LIB_VERSION,a6)
  141.     blo    gfxold$
  142.     btst    #GFXB_AA_ALICE,(gb_ChipRevBits0,a6)
  143.     beq    noaga$
  144.     move.b    (gb_MemType,a6),oldbandwidth
  145.     move.b    #BANDWIDTH_1X,(gb_MemType,a6)    ;auf ECS Wert setzen
  146.     move.l    #SETCHIPREV_A,D0
  147.     JSRLIB    SetChipRev
  148.     move.l    D0,oldchiprev
  149.     st    degraded_bdw
  150. noaga$
  151. gfxold$
  152.     RESTORE_REGS
  153.     rts
  154.  
  155. EnhanceBandWidth:
  156.     STORE_REGS
  157.     tst.b    degraded_bdw
  158.     beq    exit$
  159.  
  160.     move.l    (_GfxBase),a6
  161.  
  162.     move.l    oldchiprev,D0
  163.     JSRLIB    SetChipRev
  164.  
  165.     move.b    oldbandwidth,(gb_MemType,a6)
  166.     clr.b    degraded_bdw
  167. exit$
  168.  
  169.     RESTORE_REGS
  170.     rts
  171.  
  172. AbsFun_DegradeCpu:
  173. _DegradeCpu:
  174.     movem.l    D0/D1,-(sp)
  175.     bsr    GetVBR
  176.     move.l    D0,oldvbr
  177.     bsr    ZeroVBR
  178.     movem.l    (sp)+,D0/D1
  179.     bsr    DisCaches
  180.     move.l    D0,oldcacheset
  181.     move.b    #$00,$DE0000        ; DTack (A3000/A4000 users)
  182.     st.b    degraded_cpu
  183.     rts
  184.  
  185. AbsFun_DegradeGfx:
  186. _DegradeGfx:
  187.     bsr    OpenGFXLib
  188.     beq    D_Exit
  189.  
  190.     bsr    OpenIntuiLib
  191.     beq    D_Exit
  192.  
  193.     move.l    _IntuitionBase,D0
  194.     beq    skip$
  195.     move.l    D0,A6
  196.     sub.l    a0,a0
  197.     lea    ScreenTags,a1
  198.     JSRLIB    OpenScreenTagList
  199.     move.l    d0,TheScreen
  200.  
  201.     ; set sprite to common OCS resolution
  202.  
  203.     move.l    _GfxBase,A6
  204.     cmp.w    #39,(LIB_VERSION,a6)
  205.     blo    skip$
  206.     bsr    DegradeSprites    
  207. skip$
  208.     IFD    HDSTARTUP
  209.     move.l    _DosBase,A6
  210.     move.l    #20,D1
  211.     JSRLIB    Delay        ; wait 2/5 second before launching
  212.     ENDC
  213.  
  214.     move.l    _GfxBase,A6
  215.     move.l    gb_ActiView(A6),my_actiview
  216.     move.l    gb_copinit(A6),my_copinit
  217.     sub.l    A1,A1
  218.     JSRLIB    LoadView
  219.     JSRLIB    WaitTOF
  220.     JSRLIB    WaitTOF
  221. wav$
  222.     tst.l    (gb_ActiView,a6)
  223.     bne.b    wav$
  224.     JSRLIB    WaitTOF
  225.  
  226.     bsr    DegradeBandWidth
  227.  
  228.     IFD    HDSTARTUP
  229.     JSRGEN    ResetDisplay
  230.     ENDC
  231.  
  232.     lea    $DFF000,A5
  233.     move.w    #$0,(bplcon2,A5)
  234.     move.w    #$0,(bplcon3,A5)
  235.     move.w    #$0,(bpl1mod,A5)
  236.     move.w    #$0,(bpl2mod,A5)
  237.  
  238.  
  239. D_Exit:
  240.     st.b    degraded_gfx
  241.     rts
  242.  
  243. ; *** degrade the sprites
  244. ; *** thanks to Bert Jahn for the routine!!
  245.  
  246. DegradeSprites:
  247.     move.l    TheScreen,A0
  248.     move.l    (sc_ViewPort+vp_ColorMap,a0),a0
  249.     clr.l    -(a7)            ;TAG_DONE
  250.     clr.l    -(a7)
  251.     move.l    #VTAG_SPRITERESN_GET,-(a7)
  252.     move.l    a7,a1
  253.     move.l    _GfxBase,a6
  254.     JSRLIB    VideoControl
  255.     addq.l    #4,a7
  256.     lea    oldspriteres,a0
  257.     move.l    (a7)+,(a0)
  258.     addq.l    #4,a7
  259.     
  260.     move.l    TheScreen,a0
  261.     move.l    (sc_ViewPort+vp_ColorMap,a0),a0
  262.     clr.l    -(a7)            ;TAG_DONE
  263.     move.l    #SPRITERESN_140NS,-(a7)
  264.     move.l    #VTAG_SPRITERESN_SET,-(a7)
  265.     move.l    a7,a1
  266.     JSRLIB    VideoControl
  267.     lea    (12,a7),a7
  268.  
  269.     move.l    TheScreen,a0
  270.     move.l    _IntuitionBase,a6
  271.     JSRLIB    MakeScreen    ;force the changes
  272.     JSRLIB    RethinkDisplay
  273.  
  274.     st.b    degraded_spr
  275.     rts
  276.  
  277. EnhanceSprites:
  278.     tst.b    degraded_spr
  279.     beq    exit$
  280.  
  281.     move.l    _GfxBase,A6
  282.     move.l    TheScreen,a0
  283.     move.l    (sc_ViewPort+vp_ColorMap,a0),a0
  284.     clr.l    -(a7)            ;TAG_DONE
  285.     move.l    oldspriteres,-(a7)
  286.     move.l    #VTAG_SPRITERESN_SET,-(a7)
  287.     move.l    a7,a1
  288.     JSRLIB    VideoControl
  289.     lea    (12,a7),a7
  290.  
  291.     move.l    TheScreen,a0
  292.     move.l    _IntuitionBase,a6
  293.     JSRLIB    MakeScreen    ;force the changes
  294.  
  295.     clr.b    degraded_spr
  296. exit$
  297.     rts
  298.  
  299. ; *** Degrades everything
  300. ; in: D0,D1: value and mask for caches control
  301. ; (the same format as in CacheControl())
  302.  
  303. _C_Degrade:
  304.     move.l    4(A7),D0
  305.     move.l    8(A7),D1
  306. _Degrade:
  307. AbsFun_Degrade:
  308.     STORE_REGS
  309.  
  310.     move.l    D0,user_cacheflags
  311.     move.l    D1,user_cachemask
  312.  
  313.     bsr    _DegradeCpu        ; degrades caches, VBR, dtack
  314.     bsr    _DegradeGfx        ; degrades sprites and screen
  315.     bsr    ResetCIAs        ; re-init keyboard
  316.  
  317.     RESTORE_REGS
  318.     rts
  319.  
  320. DisCaches:
  321.     movem.l    D1-A6,-(sp)
  322.  
  323.     move.l    D0,D6
  324.     move.l    D1,D7
  325.  
  326.     bsr    _Kick37Test
  327.     tst.l    D0
  328.     bne    3$        ; Don't touch if KS 1.x
  329.  
  330.     move.l    D6,D0
  331.     move.l    D7,D1
  332.  
  333.     IFD    HDSTARTUP
  334.     tst.l    leavecaches_flag
  335.     bne    3$        ; Don't touch the caches
  336.     tst.l    nocaches_flag
  337.     beq    5$        ; Disable ALL caches
  338.     ENDC
  339.  
  340.     moveq.l    #0,D0
  341.     moveq.l    #-1,D1
  342. 5$
  343.     move.l    _SysBase,A6
  344.     JSRLIB    CacheControl
  345.     move.l    D0,D7
  346.  
  347.     move.l    _SysBase,A6
  348.     move.b    AttnFlags+1(A6),D0
  349.     btst    #AFB_68060,D0
  350.     beq    2$
  351.  
  352.     ; *** remove data cache, branch cache, write cache, superscalar mode
  353.  
  354.     lea    DisCacheSup,A5
  355.     move.l    _SysBase,A6
  356.     JSRLIB    Supervisor
  357. 2$
  358.     move.l    D7,D0
  359.     movem.l    (sp)+,D1-A6
  360.     rts
  361.  
  362. 3$
  363.     moveq.l    #0,D0
  364.     bra    2$
  365.  
  366. EnaCaches:
  367.     movem.l    D1-A6,-(sp)
  368.  
  369.     IFD    HDSTARTUP
  370.     tst.l    leavecaches_flag
  371.     bne    3$        ; Don't touch the caches
  372.     ENDC
  373.  
  374.     move.l    D0,D7
  375.     bsr    _Kick37Test
  376.     tst.l    D0
  377.     bne    3$        ; Don't touch if KS 1.x
  378.     move.l    D7,D0
  379.     move.l    _SysBase,A6
  380.     JSRLIB    CacheControl
  381.  
  382.     move.l    D0,D7
  383.  
  384.     move.l    _SysBase,A6
  385.     move.b    AttnFlags+1(A6),D0
  386.     btst    #AFB_68060,D0
  387.     beq    2$
  388.  
  389.     lea    EnaCacheSup,A5
  390.     move.l    _SysBase,A6
  391.     JSRLIB    Supervisor
  392. 2$
  393.     move.l    D7,D0
  394.     movem.l    (sp)+,D1-A6
  395.     rts
  396.  
  397. 3$
  398.     moveq.l    #0,D0
  399.     bra    2$
  400.  
  401. ; *** Disable some '060 caches
  402. ; *** Left intact by CacheControl
  403.  
  404. ; internal, only useful (and executed) for 68060 cpus
  405.  
  406. DisCacheSup:
  407.     movem.l    D1-A6,-(sp)
  408.     MACHINE    68060
  409.     ori.w    #$700,sr
  410.     movec    cacr,D0
  411.     andi.l    #$A0800000,D0
  412.     move.l    D0,old060cacr
  413.  
  414.     movec    cacr,D0
  415.     move.l    #$A0800000,D1        ; mask for specific 68060 caches
  416.  
  417.     not.l    D1
  418.     and.l    D1,D0
  419.     movec    D0,cacr
  420.  
  421.     nop
  422.  
  423.     ; *** remove superscalar
  424.  
  425.     bra    nossh$
  426.     movec    pcr,D0
  427.     move.l    D0,old060pcr
  428.     andi.l    #$04300100,D0
  429.     movec    D0,pcr
  430. nossh$
  431.  
  432.     ; *** flush
  433.  
  434.     CPUSHA    BC
  435.     movem.l    (sp)+,D1-A6
  436.     MACHINE    68000
  437.     rte
  438.  
  439. ; *** Enable some '060 caches
  440. ; *** Left intact by CacheControl
  441.  
  442. EnaCacheSup:
  443.     MACHINE    68060
  444.     ori.w    #$700,sr
  445.     movec    cacr,D0
  446.     or.l    old060cacr,D0
  447.     movec    D0,cacr
  448.  
  449.     bra    nossh$
  450.     movec    pcr,D0
  451.     or.l    old060pcr,D0
  452.     movec    D0,pcr
  453. nossh$
  454.  
  455.     CPUSHA    BC
  456.     MACHINE    68000
  457.     rte
  458.  
  459. ; *** Gets VBR value
  460. ; out: D0: VBR value
  461.  
  462. ; VBR is the vector base register (interrupts, traps, exceptions)
  463. ; It exists on 68010, 68020, 68030, 68040, 68060
  464. ; Most of the games don't like it to be different from zero,
  465. ; others are originally HD-Installable :-)
  466. ; Called from a 68000, this function will return 0 in any case (no VBR)
  467.  
  468. GetVBR:
  469.     movem.l    D1-A6,-(sp)
  470.     lea    GetVBRSup,A0
  471.     bsr    OperateVBR
  472.     movem.l    (sp)+,D1-A6
  473.     rts
  474.  
  475. ; *** Sets VBR value
  476. ; in: D0: new VBR value
  477.  
  478. ; Called from a 68000, this function will do nothing (no VBR)
  479. ; It will do nothing if the LEAVEVBR tooltype is set too (debug)
  480.  
  481. SetVBR:
  482.     movem.l    D1-A6,-(sp)
  483.     lea    SetVBRSup,A0
  484.     bsr    OperateVBR
  485.     movem.l    (sp)+,D1-A6
  486.     rts
  487.     
  488. ; *** Sets VBR to zero
  489. ; It will do nothing if the LEAVEVBR tooltype is set (debug)
  490.  
  491. ZeroVBR:
  492.     movem.l    D1-A6,-(sp)
  493.     moveq.l    #0,D0
  494.     bsr    SetVBR
  495.     movem.l    (sp)+,D1-A6
  496.     rts
  497.  
  498. ; *** VBR operation
  499. ; in: A0: supervisor function to call
  500. ;     D0: value to pass to the sup function
  501. ; out D0: return val of the sup function
  502.  
  503. ; It will do nothing if the LEAVEVBR tooltype is set (debug)
  504.  
  505.  
  506. OperateVBR:
  507.     movem.l    D1-D7/A0-A6,-(A7)
  508.     move.l    A0,A5            ; supervisor function
  509.  
  510.     move.l    _SysBase,A6
  511.     move.b    AttnFlags+1(A6),D1
  512.     btst    #AFB_68010,D1        ; At least 68010
  513.     beq    error$
  514.  
  515.     move.l    _SysBase,A6
  516.     JSRLIB    Supervisor
  517. exit$
  518.     movem.l    (A7)+,D1-D7/A0-A6
  519.     rts
  520. error$
  521.     moveq.l    #0,D0
  522.     bra    exit$
  523.  
  524. ; *** Supervisor call to set the VBR
  525.  
  526. SetVBRSup:
  527.     IFD    HDSTARTUP
  528.     tst.l    leavevbr_flag
  529.     bne    exit$
  530.     ENDC
  531.  
  532.     MACHINE 68010
  533.     movec    D0,VBR
  534.     MACHINE 68000
  535. exit$
  536.     rte
  537.  
  538. ; *** Supervisor call to get the VBR
  539.  
  540. GetVBRSup:
  541.     MACHINE 68010
  542.     movec    VBR,D0
  543.     MACHINE 68000
  544.     rte
  545.  
  546.  
  547. ; *** open graphics library
  548.  
  549. OpenGFXLib:
  550.     movem.l    D1-A6,-(sp)
  551.     lea    grname,A1
  552.     move.l    _SysBase,A6
  553.     moveq.l    #0,D0
  554.     JSRLIB    OpenLibrary
  555.     move.l    D0,_GfxBase
  556.     movem.l    (sp)+,D1-A6
  557.     rts
  558.  
  559. ; *** close graphics library
  560.  
  561. CloseGFXLib:
  562.     movem.l    D0-A6,-(sp)
  563.     move.l    _SysBase,A6
  564.     move.l    _GfxBase,D0
  565.     beq    skip$
  566.     move.l    D0,A1
  567.     JSRLIB    CloseLibrary
  568.     clr.l    _GfxBase
  569. skip$
  570.     movem.l    (sp)+,D0-A6
  571.     rts
  572.  
  573. ; *** open intuition library
  574.  
  575. OpenIntuiLib:
  576.     movem.l    D1-A6,-(sp)
  577.     lea    intname,A1
  578.     move.l    _SysBase,A6
  579.     moveq.l    #36,D0
  580.     JSRLIB    OpenLibrary
  581.     move.l    D0,_IntuitionBase
  582.     movem.l    (sp)+,D1-A6
  583.     rts
  584.  
  585. ; *** close intuition library
  586.  
  587. CloseIntuiLib:
  588.     movem.l    D0-A6,-(sp)
  589.     move.l    _SysBase,A6
  590.     move.l    _IntuitionBase,D0
  591.     beq    skip$
  592.     move.l    D0,A1
  593.     JSRLIB    CloseLibrary
  594.     clr.l    _IntuitionBase
  595. skip$
  596.     movem.l    (sp)+,D0-A6
  597.     rts
  598.  
  599.  
  600. ; *** Flushes the caches
  601.  
  602.     cnop    0,4
  603. _FlushCachesSys:
  604. AbsFun_FlushCachesSys:
  605.     STORE_REGS
  606.     bsr    _Kick37Test
  607.     tst.l    D0
  608.     bne    2$        ; Don't touch if KS 1.x
  609.     moveq.l    #0,D0
  610.     moveq.l    #0,D1
  611.     move.l    _SysBase,A6
  612.     JSRLIB    CacheControl
  613. 2$
  614.     RESTORE_REGS
  615.     rts
  616.  
  617. ; *** Test ROM version
  618. ; out: D0=0  if KS>36
  619. ;      D0!=0 if KS<=36
  620.  
  621. AbsFun_Kick37Test:
  622. _Kick37Test:
  623.     move.l    #36,D0
  624.     bsr    _KickVerTest
  625.     rts    
  626.  
  627. ; *** Test if ROM version > a given version
  628. ; in: D0: kickstart version number
  629. ; out:D0=0 newer !=0 older
  630.  
  631.     cnop    0,4
  632. AbsFun_KickVerTest:
  633. _KickVerTest:
  634.     movem.l    D1/A5/A6,-(sp)
  635.  
  636.     move.l    _SysBase,A6
  637.     move.w    SoftVer(A6),D1
  638.     cmp.w    D0,D1
  639.     bgt.s    newer$
  640.     movem.l    (sp)+,D1/A5/A6
  641.     moveq.l    #-1,D0
  642.     rts
  643. newer$
  644.     movem.l    (sp)+,D1/A5/A6
  645.     moveq.l    #0,D0
  646.     rts
  647.  
  648.  
  649.  
  650. ; *** Reset the CIAs for the keyboard
  651. ; *** Thanks to Alain Malek for this piece of code
  652. ; (see macro definition)
  653.  
  654.     IFND    HDSTARTUP
  655.     RESET_CIA_CODE
  656.     ENDC
  657.  
  658. ; ** update system time from battery backed up clock
  659.  
  660. SetClockLoad:
  661.     STORE_REGS
  662.     moveq.l    #-1,D6
  663.  
  664.     ;; snip (code in the registered version!)
  665.  
  666.     RESTORE_REGS
  667.     rts
  668.  
  669. io_request:
  670.     dc.l    0
  671. my_actiview:
  672.     dc.l    0
  673. my_copinit:
  674.     dc.l    0
  675. oldvbr:
  676.     dc.l    0
  677. oldcacheset:
  678.     dc.l    0
  679. old060cacr:
  680.     dc.l    0
  681. old060pcr:
  682.     dc.l    0
  683.  
  684. cache_value:
  685.     dc.l    0
  686. cache_mask:
  687.     dc.l    0
  688.  
  689. BattBase:
  690.     dc.l    0
  691.     IFND    HDSTARTUP
  692. _GfxBase:
  693.     dc.l    0
  694.     ENDC
  695.  
  696. _IntuitionBase:
  697.     dc.l    0
  698.  
  699. TheScreen:
  700.     dc.l    0
  701.  
  702. ScreenTags:
  703.         dc.l    SA_DisplayID,135168    ; PAL lores
  704.         dc.l    SA_Width,320
  705.         dc.l    SA_Height,200
  706.         dc.l    SA_Depth
  707.         dc.l    2            ; 4 colors
  708.         dc.l    SA_Quiet,-1
  709.         dc.l    SA_AutoScroll,0
  710.         dc.l    0,0
  711.  
  712. oldspriteres:
  713.     dc.l    0
  714. oldbandwidth:
  715.     dc.l    0
  716. oldchiprev:
  717.     dc.l    0
  718.  
  719. user_cacheflags:
  720.     dc.l    0
  721. user_cachemask:
  722.     dc.l    0
  723.  
  724. grname:
  725.     dc.b    "graphics.library",0
  726. intname:
  727.     dc.b    "intuition.library",0
  728. timername:
  729.     dc.b    "timer.device",0
  730. battname:
  731.     dc.b    "battclock.resource",0
  732.  
  733. degraded_bdw:
  734.     dc.b    0
  735. degraded_cpu:
  736.     dc.b    0
  737. degraded_gfx:
  738.     dc.b    0
  739. degraded_spr:
  740.     dc.b    0
  741. degraded_mmu:
  742.     dc.b    0
  743.  
  744.     cnop    0,4
  745.